Spice модели для TL431 + Опции

[Guest_TSerg_*]

О TL431 и дальнейших ее расширениях не знает только ленивый.

Недавно подкинули мне вроде ранее неизвестную модельку TL431 - сказали "Адекватна".
Стал проверять сразу в схемах и натыкаюсь на какие-то непонятности.
В итоге, решил заново проверить "на чистоту" все имеющиеся модели .

Результат - более, чем странный.
Несмотря на то, что TL431 и ее клонам более чем 100500 лет, Spice-модели так и не устаканились.
Из всего, что проанализировал - наилучшая (не значит - адекватная) от C.Basso (совсем не производитель TL431).
Модели от TI - неадекватны, исключая поздние с Uref = 1.25 V

Простой пример (три модели) - тест на переключение при повышении напряжения на входе от 0 до 10 V, питание 10 V через 1 кОм.
Если на входе нет токоограничивающего резистора (для разных моделей и для их адекватного поведения - он нужен разный), то результат очень странный:
http://shot.qip.ru/00gZ9L-4OPovQHsp/

***
Включение по входу резистора > 10 Ом приводит модель 2 (BASSO) в адекватное состояние.
Модели 1 (ED) для этого требуется R > 200 кОм.
Модель 3 от TI, изначально неадекватная по напряжению включения на выходе, тем не менее ведет себя адекватно, несмотря на наличие или отсутствие резистора на входе.

Единственное и логичное объяснение - модели создавались под главную функцию - "Шунтовой регулятор".
Однако реалии оказались таковы, что TL431 применяется "черти-где", включая даже как усилитель

P.S.
Ниже привожу все известные мне spice-модели TL431 и клонов.

**********************************************
* TL431
* made by Chris Basso - 2005
**********************************************
.SUBCKT TL431 k a ref
G1 a 2 5 ref -250u
Q1 k 2 1 QN3904
R1 1 7 240
R2 7 a 6.6k
Q2 k 7 a QN3904 50
D1 ref k DN4148
C2 7 a 1n
D2 a k D2_mod
C1 k 2 43p
V1 5 a DC=2.49
D3 a 2 D3_mod
.MODEL QN3904 NPN AF=1.0 BF=300 BR=7.5 CJC=3.5PF CJE=4.5PF
+ IKF=.025 IS=1.4E-14 ISE=3E-13 KF=9E-16 NE=1.5 RC=2.4
+ TF=4E-10 TR=21E-9 VAF=100 XTB=1.5
.MODEL DN4148 D BV=100V CJO=4PF IS=7E-09 M=.45 N=2 RS=.8
+ TT=6E-09 VJ=.6V
.MODEL D2_mod D BV=36 CJO=4PF IS=7E-09 M=.45 N=1.3 RS=.8
+ TT=6E-09 VJ=.6V
.MODEL D3_mod D N=0.01
.ENDS

*********************************
* K A FDBK
* | | |
*********************************
.SUBCKT TL431_MC 7 6 11
.MODEL DCLAMP D (IS=13.5N RS=25M N=1.59 CJO=45P VJ=.75 M=.302 TT=50.4N BV=34V IBV=1MA)
*EB1 1 6 Value = { IF ( V(7,6)> 2.495, 2.495, V(7,6) ) }
*V1 1 6 2.495 ; used for fixed reference, replaced with EB1 Limiter
V1 1 6 2.495
R1 6 2 15.6
C1 2 6 .5U
R2 2 3 100
C2 3 4 .08U
R3 4 6 10
G2 6 8 3 6 1.73
D1 5 8 DCLAMP
D2 7 8 DCLAMP
V4 5 6 2
G1 6 2 1 11 0.11
.ENDS TL431_MC

***************************
* TL431 MACROMODEL
* 3-26-92
*
* REFERENCE
* | ANODE
* | | CATHODE
* | | |
***************************
.SUBCKT TL431_TI 1 2 3
V1 6 7 DC 1.4V
I1 2 4 1E-3
R1 1 2 1.2E6
R2 4 2 RMOD 2.495E3
R3 5 7 .2
D1 3 6 DMOD1
D2 2 3 DMOD1
D3 2 7 DMOD2
E1 5 2 POLY(2) (4,2) (1,2) 0 710 -710
.MODEL RMOD RES (TC1=1.4E-5 TC2=-1E-6)
.MODEL DMOD1 D (RS=.3)
.MODEL DMOD2 D (RS=1E-6)
.ENDS

*****************************
* TL431 Current Regulator
* C A Ref
* | | |
*****************************
.subckt TL431 7 6 11
Q1 N004 N003 N001 0 P
Q2 6 N002 N001 0 P
Q3 7 N005 6 0 N
R1 N002 6 600k
R2 11 N002 648k
I1 7 N001 5u
V1 N003 6 1.2V
Q4 7 N004 N005 0 N
R6 N004 6 640k
.model N NPN(BF=250 Cje=.5p Cjc=.5p Rb=500)
.model P PNP(BF=120 Cje=.3p Cjc=1.5p Rb=250)
.ends TL431

***************************************
* TLVH431
* © Copyright 2010 Texas Instruments Incorporated.
***************************************
*.SUBCKT TLVH431 A K Fdbk
.SUBCKT TLVH431 A K RF
V_V2 N59715 A 1.24
G_G4 K A TABLE { V(STAGE2, A) }
+ ( (-10,0)(0,0)(80m,80m)(10,81m) )
R_R1 A STAGE1 1
R_R2 A STAGE2 1
C_C2 A STAGE1 159e-6
C_C3 A STAGE2 80n
G_G1 A STAGE1 RF N59715 4
X_D1 A STAGE1 DC_1mV_1A_1V_1nA
G_G3 A STAGE2 STAGE1 A 1
X_D2 STAGE1 N59689 DC_1mV_1A_1V_1nA
X_D3 A K DC_1mV_1A_1V_1nA
V_V1 N59689 A 80m
.ENDS TLVH431
*$
.subckt DC_1mV_1A_1V_1nA A C
G1 A C TABLE { V(A, C) } ( (-1,-1n)(0,0)(1m,1) (2m,10) (3m,1000) )
.ends DC_1mV_1A_1V_1nA
*$

**************************
* TLVH431 Shunt regulator
**************************
.SUBCKT TLVH431b 7 6 11
V1 1 6 1.24
R1 6 2 15.6
C1 2 6 .5U
R2 2 3 100
C2 3 4 .08U
R3 4 6 10
G2 6 8 3 6 1.73
D1 5 8 DC
D2 7 8 DC
V4 5 6 2
G1 6 2 1 11 0.11
.MODEL DC D (IS=13.5N RS=25M N=1.59 CJO=45P VJ=.75 M=.302 TT=50.4N BV=34V IBV=1MA)
.ENDS TLVH431

[Guest_TSerg_*]

Информация получена сегодня от Амелиных, Марины и Сергея, выкладываю

Часть работы студентов под их руководством по изучению моделей TL431.
 Models_of_TL431.pdf ( 469.34 килобайт ) Кол-во скачиваний: 249


P.S.
Мне тоже пришлось заняться реверсом функциональных моделей TL431 по spice-моделям.
Поэтому, вдвойне приятно совпадение взглядов и результатов.

[rudy_b]

Я пользуюсь такой

CODE

* Model developed by Eugene Dvoskin --> "http://www.audio-perfection.com" 02/05/2012
* This TL431 model has been developed from schematic in the
* datasheet http://www.ti.com/lit/ds/symlink/tl431.pdf
* It matches most of DC, AC, Transient, Stability and Noise performance of TI TL431
* No attempts were made to cover Temperature dependences
.subckt TL431ED K A ADJ
Q1 K ADJ N005 0 QN_ED
R4 N005 N009 3.28k
R2 N009 N012 2.4k
R3 N009 N010 7.2k
Q2 N012 N012 A QN_ED 1.2
Q3 N010 N012 N014 QN_ED 2.2
R1 N014 A 800
Q4 N003 N005 N006 0 QN_ED
R5 N006 N011 4k
Q5 N011 N010 A QN_ED
Q6 N004 N013 A QN_ED 0.5
Q7 N003 N003 N001 QP_ED
Q8 N004 N003 N002 QP_ED
R7 K N001 800
R8 K N002 800
Q9 K N004 N007 QN_ED
R9 N008 N007 150
Q10 K N008 A 0 QN_ED 5
R10 N008 A 10k
Q11 N004 N004 ADJ QN_ED
D1 A N004 D_ED
R6 N013 N012 1k
D2 A K D_ED
C1 K N004 10p
C2 N010 N011 20p
.model QN_ED NPN(BF=140 Cje=1p Cjc=2p Rb=40 VAF=80 VAR=50 KF=3.2e-16 AF=1)
.model QP_ED PNP(BF=60 Cje=1p Cjc=3p Rb=80 VAF=70 VAR=40)
.MODEL D_ED D(Rs=5 CJO=4.0p)
.ends TL431ED

Вроде все работает нормально. Мне нужен был шум, котороый в стандартной модели нулевой. Шум этой модели близок к реальному. Буковки ED в названии ничего не значат, только для отличия этой модели от стандартной.

[Guest_TSerg_*]

Спасибо, эта моделька мне тоже известна и базируется на почти полной схемотехнической копии TL431:
http://shot.qip.ru/00gZ9L-2OPovQHsR/
Буковки ED в названии означают модель от "Eugene Dvoskin".

И вот к ней, тоже претензии есть (по входу REF неадекватное поведение выхода).

Пример:

Схема R2 = 0 (неадекватное поведение)
http://shot.qip.ru/00gZ9L-4OPovQHsS/
DC-DC
http://shot.qip.ru/00gZ9L-6OPovQHsU/

Схема R2 = 1k (неадекватное поведение)
http://shot.qip.ru/00gZ9L-4OPovQHsV/
DC-DC
http://shot.qip.ru/00gZ9L-4OPovQHsW/

Схема R2 = 100k (неадекватное поведение)
http://shot.qip.ru/00gZ9L-6OPovQHsZ/
DC-DC
http://shot.qip.ru/00gZ9L-6OPovQHt0/

Схема R2 = 200k (адекватное поведение)
http://shot.qip.ru/00gZ9L-4OPovQHt2/
DC-DC
http://shot.qip.ru/00gZ9L-2OPovQHt4/

Аналогично и по температуре неадекватно:
- температурный сдвиг Uref во всем температурном диапазоне составляет 6 mV для гр. B и 14 mV для гр. I, Q по даташиту.
В модели ED в диапазоне -40..+85 С (гр.I) сдвиг составляет 74 mV.

[rudy_b]

Во всех ваших случаях неадекватности напряжение на входе Ref больше напряжения на катоде - это нештатный режим работы. В штатных режимах все нормально.

Скорее всего в схеме TL431 от TI не показаны какие-то элементы защиты, вот их и не учел ED.

А, возможно, реальный чип так себя и ведет - я не гонял его в таких режимах.

Да, а температурную зависимость эта модель честно, с предупреждением, не отражает.

[Guest_TSerg_*]

Во всех ваших случаях неадекватности напряжение на входе Ref больше напряжения на катоде - это нештатный режим работы. В штатных режимах все нормально.

Я сразу вначале оговорился, что поскольку давно наблюдается тенденция использование TL431 и его клонов в черти каких, но в допустимых режимах - возникают вопросы к моделям.
Поэтому и захотелось разобраться, с какими моделями можно работать в условиях по даташиту, но со свободным использованием выводов.

Короче, вот съемка реальных значений с TL431 (Uпит = 12 В, ток катода = 10 мА):
Характеристики Uout (Uref)

До переключения (выключенное состояние):
http://shot.qip.ru/00gZ9L-2OPovQHtt/

Режим переключения (на половине шкалы наблюдается усилительный режим, что и понятно):
http://shot.qip.ru/00gZ9L-4OPovQHtv/

Режим насыщения (включенное состояние)
http://shot.qip.ru/00gZ9L-4OPovQHtx/
Видны нелинейные переходные процессы в статике, но напряжение остается в рамках 2 В, а не лезет наверх к Uпит., как в некоторых моделях.

P.S.
Разумеется, надо иметь в виду при использовании таких режимов, входной ток по даташиту ограничен стрессовым значением 10 мА.
В данном случае, при напряжении питания 12 В, ограничивающем по входу REF резисторе 1 кОм и напряжении на REF = 3 V - имеем входной ток 9 мА, т.е. мы не превысили допустимый ток по входу в режиме стресса.
В общем, рекомендация такова (что давно подтверждено практикой):
Режим работы без ОС с катода возможен, в т.ч. и при превышении напряжения на REF напряжения на катоде,
надо только ограничивать входной ток путем включения по входу резистора из расчета не превышения допустимого тока в стрессовом режиме, но желательным все же является ток на уровне нормальных рекомендованных условий.

[Guest_TSerg_*]

Мне нужен был шум, котороый в стандартной модели нулевой. Шум этой модели близок к реальному.

Шум в модели ED - фиктивный. (даже есть тесты по шуму с моделью ED, но внимательное изучение показывает их неадекватность, точнее - это вычислительный шум).
В модели ED нет никаких явных источников шума с теми или иными параметрами, как нет и полупроводников с моделью шума.

P.S.
Когда я вижу вот такие "вещи", которые зависят от дискрета по времени, я не доверяю модели от слова "совсем":
- дискрет 1 ns:
http://shot.qip.ru/00gZ9L-2OPovQHtM/
- дискрет 10 ns:
http://shot.qip.ru/00gZ9L-6OPovQHtQ/
- дискрет 100 ns:
http://shot.qip.ru/00gZ9L-2OPovQHtR/

[rudy_b]

Я делал хитрозадую схему и получил шум в десятки раз больше, чем ожидал. Начал разбираться. Модель от TI не шумит вообще (как выяснилось), но, в даташите, указаны значения близкие к правде. Нашел модель ED которая дает близкий к реальному шум. Никакие особые генераторы шума не нужны, модели транзисторов сразу дают шум, близкий к реальному.

А при симуляциях во времени шум оценить трудно - большую и неконтролируемую болтанку дает сам симулятор - плохая сходимость. Нормальную оценку можно сделать только в спектральном анализе и вот там получаются близкие к реальности значения.

[Guest_TSerg_*]

Я делал хитрозадую схему и получил шум в десятки раз больше, чем ожидал. Начал разбираться. Модель от TI не шумит вообще (как выяснилось), но, в даташите, указаны значения близкие к правде. Нашел модель ED которая дает близкий к реальному шум. Никакие особые генераторы шума не нужны, модели транзисторов сразу дают шум, близкий к реальному.

А при симуляциях во времени шум оценить трудно - большую и неконтролируемую болтанку дает сам симулятор - плохая сходимость. Нормальную оценку можно сделать только в спектральном анализе и вот там получаются близкие к реальности значения.

Ткните пальцем, где Вы тут шум в каком-либо элемента нашли?

.subckt TL431_EDV K A ADJ
Q1 K ADJ N5 0 QN_ED
R4 N05 N09 3.28k
R2 N09 N12 2.4k
R3 N09 N10 7.2k
Q2 N12 N12 A QN_ED 1.2
Q3 N10 N12 N14 QN_ED 2.2
R1 N14 A 800
Q4 N03 N05 N06 0 QN_ED
R5 N06 N11 4k
Q5 N11 N10 A QN_ED
Q6 N04 N13 A QN_ED 0.5
Q7 N03 N03 N01 QP_ED
Q8 N04 N03 N02 QP_ED
R7 K N01 800
R8 K N02 800
Q9 K N04 N07 QN_ED
R9 N08 N07 150
Q10 K N08 A 0 QN_ED 5
R10 N08 A 10k
Q11 N04 N04 ADJ QN_ED
D1 A N04 D_ED
R6 N013 N012 1k
D2 A K D_ED
C1 K N04 10p
C2 N010 N011 20p
.model QN_ED NPN(BF=140 Cje=1p Cjc=2p Rb=40 VAF=80 VAR=50 KF=3.2e-16 AF=1)
.model QP_ED PNP(BF=60 Cje=1p Cjc=3p Rb=80 VAF=70 VAR=40)
.MODEL D_ED D(Rs=5 CJO=4.0p)
.ends TL431_EDV

[rudy_b]

Каждое сопротивления в модели транзистора вносит свой шум и это дает правильную оценку шума на частотах выше фликкера. Многократно проверял - все близко к правде. В даташите на TL431 уровень шума (выше фликкера) указан порядка 120 нв/sqrt(Гц), модель дает порядка 140 (что ближе к правде). Привел шум из даташита и из модели ED.

Вот когда считаешь малошумящие схемы - в них действительно вводят дополнительные независимые источники шума (кроме стандартных). Но это делается только для упрощения - точную модель входного транзистора сделать непросто, поэтому берут нешумящий транзистор и добавляют к нему шум.

[Plain]

вот съемка реальных значений с TL431

А вот реальная съёмка TL431:

http://www.righto.com/2014/05/reverse-engi...ost-common.html

Ключевое замечание от автора, что содранные значения сильно отличаются от присутствовавших в ранее опубликованных схемах, например этой:



Ну и наверное то, что без хотя бы приблизительного знания отношения площадей подобные схемы вообще трудно понимаемы.

[Guest_TSerg_*]

в модели транзистора

Я не обратил внимание на ненулевые значения параметров AF и KF для задания фликкер-шума, так, что все в порядке - шум есть
Что-то похожее на правду для одиночного транзистора NPN в модели ED:
http://shot.qip.ru/00gZ9L-3OPovQHvG/

И весьма занятный шум, для модели TL431 от ED:

В диапазоне >10 Гц при Rг = 0 просто фантастика, но не реальная:
http://shot.qip.ru/00gZ9L-1OPovQHvL/
В диапазоне >10 Гц при Rг = 27к близко к ДШ:
http://shot.qip.ru/00gZ9L-6OPovQHvN/
И, в целом, по диапазону (Rг = 0):
http://shot.qip.ru/00gZ9L-1OPovQHvK/

При Rг > 27к происходит резкий подъем шума до 400n.
В общем, опять все плохо согласуется с реальностью.

[rudy_b]

Ты смотришь не тот шум - ONOISE вместо INOISE. Он не прописан в даташите. Посмотри график V(INOISE) который я приводил (нижний).

И нужно правильно включить источник напряжения, к которому приводится входной шум.

[Guest_TSerg_*]

Ты смотришь не тот шум - ONOISE вместо INOISE.

Ок, верно - я же смотрел выходной шум.
По входу модель адекватна:
http://shot.qip.ru/00gZ9L-6OPovQHvU/
Схема измерения:
http://shot.qip.ru/00gZ9L-3OPovQHvV/

[rudy_b]

Ага, все верно. У меня делитель Ref - 2 резистора по 10к, питание 12в через 1к, но это несущественно.

[Guest_TSerg_*]

Ага, все верно. У меня делитель Ref - 2 резистора по 10к, питание 12в через 1к, но это несущественно.

По даташитам измерения идут на 10 мА, так, что важно - это.

По температуре модель от ED, неадекватна, как качественно, так и количественно:
http://shot.qip.ru/00gZ9L-4OPovQHvW/
154 mV против 14..34 mV (гр. I,Q) в температурном диапазоне -40..+85 С.

Адекватная (по температуре) модель от TI (14 mV):
http://shot.qip.ru/00gZ9L-4OPovQHvY/

[Guest_TSerg_*]

Еще одним эффективным методом проверки spice-модели (и не только) и сверки с реальным образцом (а, потом и наоборот), является давно известный и применяемый метод - "ступенька".
Для примера, реакция на ступеньку двух моделей:
- Chr. Basso:
http://shot.qip.ru/00gZ9L-2OPovQHwr/
- Eug. Dvoskin:
http://shot.qip.ru/00gZ9L-4OPovQHwq/

Близким же к реальности, является переходной процесс из даташита:
http://shot.qip.ru/00gZ9L-6OPovQHws/

[rudy_b]

Ты про всякие емкости в схеме не забыл?

[Guest_TSerg_*]

Ты про всякие емкости в схеме не забыл?

Внутри? Это дело дизайнеров моделей, что и проверяем.
Снаружи нет никаких емкостей - все по схеме тестирования, рекомендуемой TI, LT в их даташитах.
Паразитные C, L - это смешные, для такого девайса.

P.S.
Схема, рекомендованная по даташиту:
http://shot.qip.ru/00gZ9L-6OPovQHws/

Посмотрев на все плохие варианты, схему перевел на меньшее напряжение тестового импульса, но ток 4..5 мА.

P.S.
Да, извиняюсь - тест-схема такова:
http://shot.qip.ru/00gZ9L-1OPovQHwz/
Вывод adj (ref) можно подключать/отключать - не влияет в данном варианте.

В итоге, для модели Basso - вот такая "петрушка":
http://shot.qip.ru/00gZ9L-1OPovQHwA/
Для модели Dvoskin (ED):
http://shot.qip.ru/00gZ9L-6OPovQHwB/

[rudy_b]

Вообще - то, импульсная характеристика TL431 из последнего (SLVS543O–AUGUST 2004–REVISED JANUARY 2015) даташита выглядит совершенно иначе, чем ты приводил тут
.
А есть еще и это

Отсюда понятно, что TI безбожно врет относительно своей детали - со временем увидишь сам. А если внимательно посмотришь на приведенную тобой импульсную характеристику, то заметишь, что это не переколебон, а несколько перескоков.

На самом деле более интересно сравнивать эти параметры

[wim]

для модели Basso - вот такая "петрушка"

ПМСМ, модели Бассо нужно сравнивать с TL431 пр-ва On Semiconductor, т.к. он в основном для них свои модели и мастерит.

[Guest_TSerg_*]

импульсная характеристика TL431 из последнего (SLVS543O–AUGUST 2004–REVISED JANUARY 2015)

Есть у меня это, но это вообще ни о чем.
Fairchild приводила похожие хар-ки, но это далеко от реальности:
http://shot.qip.ru/00gZ9L-3OPovQHwK/

А есть еще и это

Это понятно, что будут изменения в зависимости от резисторов делителя.

А если внимательно посмотришь на приведенную тобой импульсную переходную характеристику, то заметишь, что это не переколебон, а несколько перескоков.

О чем и говорю, что там не просто колебательное звено, но нелинейное

На самом деле более интересно сравнивать эти параметры

Ну да, это след. этап.

[Guest_TSerg_*]

Отсюда понятно, что TI безбожно врет относительно своей детали

"Они вообще все и всЕ врут" (С) Jeer
***
Варианты переходной хар-ки (по производителям и экземплярам):
Серия 1:
1.1. http://shot.qip.ru/00gZ9L-2OPovQHwN/
1.2. http://shot.qip.ru/00gZ9L-1OPovQHwR/
1.3. http://shot.qip.ru/00gZ9L-1OPovQHwS/

Серия 2:
2.1. http://shot.qip.ru/00gZ9L-2OPovQHwO/
2.2. http://shot.qip.ru/00gZ9L-3OPovQHwP/
2.3. http://shot.qip.ru/00gZ9L-6OPovQHwQ/

P.S.
Собственно, что мы видим - САР с наличием ПИД-регулирования.
Интегральная составляющая срабатывает на интервале до 500..600 ns.

[rudy_b]

Мелкие отличия. Так какая модель самая верная по импульсной характеристике?

[Guest_TSerg_*]

Мелкие отличия. Так какая модель самая верная по импульсной характеристике?

У меня немного другая задача(и):
- личная - по изучению вариантов TL431 по производителям и экземплярам;
- поставленная - по созданию адекватной отечественной spice-модели для отечественного клона.

[AML]

- поставленная - по созданию адекватной отечественной spice-модели для отечественного клона.

А по какому набору параметров планируется оценивать адекватность?

[Herz]

- поставленная - по созданию адекватной отечественной spice-модели для отечественного клона.

И адекватна чему должна быть модель "отечественного клона"? Если это - полноценная разработка аналога, то и модели должны быть разработаны заново, нет?

[Guest_TSerg_*]

А по какому набору параметров планируется оценивать адекватность?

Ну, как минимум S-параметры
Сейчас идет съем характеристик сотен экземпляров, тех или иных.
В реальности - все возможные статические, динамические, термо- параметры.
Вот только потом - создание спайс-моделей под задачи.
P.S.
Модели Basso & Dvoskin - не интересны. Они просто рассмотрены, как имеющиеся.

[Guest_TSerg_*]

Если это - полноценная разработка аналога, то и модели должны быть разработаны заново, нет?

Да.
Это разработка на местном "свечном" заводике спектра клонов с Uref = 1.25 и 2.5, radhard.
Грант выдан, участвуют студенты старших курсов, ну и мэтры.
Я - куратор по студентам и проекту, не исполнитель.

[Guest_TSerg_*]

На днях, мне подкинули еще одну spice-модель TL431, от отечественного spice-дизайнера (пусть будет ник PSH).
Исходная модель мне неизвестна.

P.S.
Сделал предварительные тесты.
Если автор захочет и разрешит - выложу спайс с авторством и результаты тестирования.
Впрочем, обезличенные результаты, полагаю можно выложить не спрашивая разрешения.

1. Переходная характеристика реального образца TL431.
Что мы видим на переходном процессе (ПП)?
- тонкую структуру дифф. типа в начале ПП;
- пропорционально-интегральный ПП.
Время установления ~ 500 ns
http://savepic.ru/12508703.jpg

2. Предложенная автором PSH - модель TL431 .
Что мы видим на ПП?
- отсутствует тонкая структура в начале ПП;
- процесс автоколебательный, с большим временем установления;
Время установления - 1500 ns (в 3 раза более, чем у реального образца)
http://savepic.ru/12514846.png

3. Температурная характеристика.
(это один из главных показателей прецизионного стабилитрона).
Что мы видим в предложенной модели?
http://savepic.ru/12469777.png
В температурном диапазоне (минус 40 .. + 85) - кошмарные 147 мВ дрейфа Uref.
К тому же, смещен минимум TEMP-погрешности - от 25 С в плюс до 40 С.
P.S.
По ТТХ TL431 допустимо всего 6..14 mV в указанном диапазоне TEMP.

4. АЧХ.
TL431 - это усилитель/компаратор с обратной связью.
АЧХ - еще один важный показатель идентификации как модели, так и экземпляра.
Для модели PSH, увы - абсолютно не адекватная АЧХ, особенно - по коэффициенту усиления.
"Редкая птица" из TL431 превышает 60 дБ усиления.
В модели PSH мы видим пойчти +80 дБ - анриал.
http://savepic.ru/12502546.png

5. Входная реверс-характеристика.
Поскольку объект изучения - это "стабилитрон", то важным является изучение обратной вольт-амперной характеристки (ВАХ).
ВАХ делим на три участка: минимальный, нормальный, максимальный.
- минимальный - это изучение поведения прибора на переходе от минимальных токов к нормальным;
- нормальный - это изучение поведения прибора в диапазоне нормальных токов;
- максимальный - это изучение поведения прибора свыше нормальных токов.
(статика, без ограничения по мощности)

5.1. Минимальный режим:
http://savepic.ru/12465682.png
Удовлетворительно моделирует реальность
5.2. Нормальный режим:
Хорошо моделирует реальность
http://savepic.ru/12505621.png
5.3. Максимальный режим.
Удовлетворительно моделирует реальность
http://savepic.ru/12497429.png