Модель APT47N60BC3G для OrCAD, Помогите создать рабочую модель Опции

[gregory812]

Есть фирменная модель для PSPICE транзистора APT47N60BC3G.lib. Пытался просто через PSPICE Model Editor преобразовать в файл .olb. Но при моделирование говорит, что неправильная модель. Подскажите, что нужно скорректировать, чтобы заработало. Спасибо.

*****************************************************************************
* Microsemi Corporation
* Power Products Group
*
* Part APT60N60BCSG.lib
* Created Sept 13, 2007
*
* This SPICE model was created to simulate the characteristics of a typical
* device. However, as with any simulation model, it is not feasible to model
* exact device performance under all operating conditions. Microsemi does
* not assume any liability as a result of the use of SPICE models. Please
* refer to the device datasheet for ratings and detailed device
* characterization. In addition to simulation, operation of this device
* should be verified by testing in circuit.
*
* Microsemi reserves the right to change SPICE models without notice.
*
* For applications support, call: +1 541-382-8028
* or email: applications-1@microsemi.com
*****************************************************************************
*SRC=APT60N60BCSG0;APT60N60BCSG;User Imports;Mosfets;CoolMOS 600V 60A n-channel
*SYM=POWMOSN
.SUBCKT APT60N60BCSG drain gate source

Lg gate g1 7n
Ld drain d1 3n
Ls source s1 7n
Rs s1 s2 1m
Rg g1 g2 1.3
M1 d2 g2 s2 s2 DMOS L=1u W=1u
.MODEL DMOS NMOS ( KP= 112.533 VTO=3.85 THETA=0 VMAX=1.5e5 ETA=0 LEVEL=3)
Rd d2 d1a RdMOD 0.034
.model RdMOD R TC1=13m
.MODEL MVDR NMOS (KP=272.45 VTO=-1 LAMBDA=0.15)
Mr d1 d2a d1a d1a MVDR W=1u L=1u
Rx d2a d1a 1m
Cds1 s2 d2 195.5p
Dbd s2 d2 Dbt
.MODEL Dbt D(BV=600 M=0.85 CJO=88.84n VJ=0.5V)
Dbody s2 21 DBODY
.MODEL DBODY D(IS=42.1p N=1.08 RS=2u EG=1.12 TT=750n)
Rdiode d1 21 RdiodeMOD 1.69m
.model RdiodeMOD R TC1=6m
.MODEL sw NMOS(VTO=0 KP=10 LEVEL=1)
Maux g2 c a a sw
Maux2 b d g2 g2 sw
Eaux c a d2 g2 1
Eaux2 d g2 d2 g2 -1
Cox b d2 5.51n
.MODEL DGD D(M=0.999 CJO=5.51n VJ=0.5)
Rpar b d2 1Meg
Dgd a d2 DGD
Rpar2 d2 a 10Meg
Cgs g2 s2 6.81n
.ENDS APT60N60BCSG

Сообщение отредактировал gregory812 - May 21 2008, 12:00

[bezobraznic]

зайди в Simulation settings-> Configuration files ->Library и укажи путь на lib файл модели.