Как настроить SDRAM на EP93xx? Опции

[Andrei....]

Как настроить SDRAM на EP93xx? Очень хотелось бы взглянуть на пример кода.

[aaarrr]

Вот пример инициализации на asm'е для 32-х бит, закомменченные значения, насколько я помню,
для 16...

Код

; ***************************************************************************
; * SDRAM Controller Configuration

; 1. Wait 100us

; 2. Set SDRAM controller device mode register
        ldr        r0, =0x01210008    ;0x0022000c
        ldr        r1, =SDRAMDevCfg0
        str        r0, [r1]
        ldr        r1, =SDRAMDevCfg1
        str        r0, [r1]
        ldr        r1, =SDRAMDevCfg2
        str        r0, [r1]
        ldr        r1, =SDRAMDevCfg3
        str        r0, [r1]

        ldr        r1, =GlConfig
        ldr        r2, =RefrshTimr

; 3. Set Initialize, MRS, and CKE bits in the GlConfig register

        ldr        r0, =0x80000003
        str        r0, [r1]

; 4. Wait 200us
        mov        r0, #0x4000
1
        subs    r0, r0, #0x01
        bne        %B1

; 5. Clear MRS bit
        ldr        r0, =0x80000001
        str        r0, [r1]

; 6. Write 10 into the refresh timer register
        mov        r0, #0x0a
        str        r0, [r2]

; 7. Wait at least 80 clock cycles
        mov        r0, #0x100
1
        subs    r0, r0, #0x01
        bne        %B1

; 8. Program the refresh counter
        mov        r0, #0x320
        str        r0, [r2]

; 9. Initialize = 0, MRS = 1
        ldr        r0, =0x80000002
        str        r0, [r1]

        ldr        r0, =0xc0008800    ;0xf0006600
        ldr        r0, [r0]

; 10.

; 11. Clear MRS
        ldr        r0, =0x80000000
        str        r0, [r1]