Неясность с выходным напряжением LM119 при симуляции, напряжение низкого уровня не зависит от GND Опции

[Ilya_NSK]

Компаратор LM119 имеет двуполярное питание, выход с открытым коллектором и отдельный вывод "земли":



Насколько я понимаю, лог.0 на выходе определяется как раз потенциалом GND. Однако, при моделировании в Multisim возникла странная ситуация. При V+/- = +/-12В, OUTPUT на +6В через 1k и GND на общий провод (т.е. 0 В) лог.1 на выходе получается нормальная (порядка +6В), а вот лог. 0 составляет -11.5В, т.е., фактически, V-. При этом вывод GND симулятором, по-моему, вообще игнорируется: его можно кинуть на V-, V+ или даже оставить не подключенным - ничего не меняется.
В LTSpice и Tina-Ti такого компаратора нет. Скачал модель с сайта ST. Я в SPICE не понимаю, но по-моему, в комментарии к этой модели вообще вывод GND не упоминается:

CODE

* WARNING : please consider following remarks before usage
* 1) All models are a tradeoff between accuracy and complexity (ie. simulation time).
* 2) Macromodels are not a substitute to breadboarding, they rather confirm the validity of a design approach and help to select surrounding component values.
* 3) A macromodel emulates the NOMINAL performance of a TYPICAL device within SPECIFIED OPERATING CONDITIONS (ie. temperature, supply voltage, etc.).
* Thus the macromodel is often not as exhaustive as the datasheet, its goal is to illustrate the main parameters of the product.
* 4) Data issued from macromodels used outside of its specified conditions (Vcc, Temperature, etc) or even worse: outside of the device operating
* conditions (Vcc, Vicm, etc) are not reliable in any way.
*-----------------------------------------------------------------------------------------
* LM119/LM219/LM319 spice macromodel
* CONNECTIONS :
* 1 NON-INVERTING INPUT
* 2 INVERTING INPUT
* 3 POSITIVE POWER SUPPLY
* 4 NEGATIVE POWER SUPPLY
* 5 OUTPUT
*
**********************************************************
.SUBCKT LMx19 2 1 44 55 33
EVCCP 4 0 44 0 1.0
EVCCN 5 0 55 0 1.0
VREADIO 3 33 DC 0
R_ICCSAT_HIGH ICC_OUT_HIGH 0 1k
R_ICCSAT_LOW ICC_OUT_LOW 0 1k
G_ICCSAT 44 55 VALUE={IF(V(3)>(V(44)+V(55))/2, V(Icc_out_high), V(Icc_out_low) ) }
E_ICCSAT_HIGH ICC_OUT_HIGH 0 VALUE={4E-4*V(44,55)}
E_ICCSAT_LOW ICC_OUT_LOW 0 VALUE={1E-3 + 1E-4*V(44,55)}
G_IOUT_SINKED 55 0 VALUE={IF (V(1)<V(2), 0, I(VreadIo))}
.MODEL MDTH D IS=1E-11 KF=1.050321E-32 CJO=10F
* INPUT STAGE
CIP 2 5 1.000000E-12
CIN 1 5 1.000000E-12
EIP 102 0 2 0 1
VIO 10 102 880U
EIN 16 0 1 0 1
RIP 10 11 6.500000E+01
RIN 15 16 6.500000E+01
RIS 11 15 1.939046E+02
DIP 11 12 MDTH 400E-12
DIN 15 14 MDTH 400E-12
VOFP 12 13 DC 0.000000E+00
VOFN 13 14 DC 0
IPOL 13 0 100E-06
CPS 11 15 3.7E-10
DINN 17 13 MDTH 400E-12
VIN 17 5 2.000000E+00
DINR 15 18 MDTH 400E-12
VIP 4 18 2.000000E+00
FCP1 4 0 VOFP 80
FCP2 0 4 VOFN 80
FCN1 0 5 VOFP 30
FCN2 5 0 VOFN 30
FIBP 2 0 VOFN 3E-03
FIBN 0 1 VOFP 3E-03
* AMPLIFYING STAGE
RG1 5 19 2.85E+05
RG2 4 19 2.85E+05
DOP 19 25 MDTH 400E-12
VOP 4 25 1.097
DON 24 19 MDTH 400E-12
VON 24 5 1.097
FIP 0 19 VOFP -104
FIN 0 19 VOFN -104
EOUT 26 5 19 5 1
.MODEL NMOD NPN(IS=0.1E-09 BF=1500)
RBOUT 27 26 800K
QOUT 103 27 28 28 NMOD
RCEOUT 103 28 15.02E+07
REOUT 28 5 20
RSOUT 3 0 1E+12
VNUL 3 103 0
.ENDS

В Multisim модель, насколько я могу судить, даже "беднее" - нет тех параметров, которые в самом начале модели ST (EVCCP, EVCCN, VREADIO и т.п.):

CODE

################## Model Data Report ##################
============= SPICE Model =================
** CONNECTIONS :
* 1 INVERTING INPUT
* 2 NON-INVERTING INPUT
* 3 OUTPUT
* 4 POSITIVE POWER SUPPLY
* 5 NEGATIVE POWER SUPPLY
.SUBCKT LM119 1 2 3 4 5
CIP 2 5 1.000000E-12
CIN 1 5 1.000000E-12
EIP 102 0 2 0 1
VIO 10 102 880U
EIN 16 0 1 0 1
RIP 10 11 6.500000E+01
RIN 15 16 6.500000E+01
RIS 11 15 1.939046E+02
DIP 11 12 MDTH 400E-12
DIN 15 14 MDTH 400E-12
VOFP 12 13 DC 0
VOFN 13 14 DC 0
IPOL 13 0 100E-06
CPS 11 15 3.7E-10
DINN 17 13 MDTH 400E-12
VIN 17 5 2.0
DINR 15 18 MDTH 400E-12
VIP 4 18 2.0
FCP1 4 0 VOFP 80
FCP2 0 4 VOFN 80
FCN1 0 5 VOFP 30
FCN2 5 0 VOFN 30
FIBP 2 0 VOFN 3E-03
FIBN 0 1 VOFP 3E-03
* AMPLIFYING STAGE
RG1 5 19 2.85E+05
RG2 4 19 2.85E+05
DOP 19 25 MDTH 400E-12
VOP 4 25 1.097
DON 24 19 MDTH 400E-12
VON 24 5 1.097
FIP 0 19 VOFP -104
FIN 0 19 VOFN -104
EOUT 26 5 19 5 1
RBOUT 27 26 800K
QOUT 103 27 28 28 NMOD
RCEOUT 103 28 15.02E+07
REOUT 28 5 20
RSOUT 3 0 1E+12
VNUL 3 103 0
.MODEL NMOD NPN(IS=0.1E-09 BF=1500)
.MODEL MDTH D IS=1E-11 KF=1.050321E-32 CJO=10F
.ENDS
============= Model template =================
x%p_a %tIN- %tIN+ %tOUT %tVS+ %tVS- %m

Правда, в секции "Model template", где, насколько я понимаю, перечислены типа как передаваемые оболочкой симулятору данные, параметров 7, а не 5. Но что это за параметры и как их понимать - я не знаю.

Правильно ли я понял, что это сами модели "кривые" и пытаться запихать их в другой симулятор бесполезно? Если да, то как из этой ситуации выпутаться?

Сообщение отредактировал Ilya_NSK - Oct 14 2016, 16:20

[SSerge]

Попробуйте эту, из Оркада:

CODE

*-----------------------------------------------------------------------------
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | open collector output
* | | | | | output ground
* | | | | | |
.subckt LM119 1 2 3 4 5 6
*
f1 3 9 v1 1
iee 7 4 dc 100.0E-6
q1 9 2 7 qin
q2 8 1 7 qin
q3 9 8 3 qmo
q4 8 8 3 qmi
.model qin NPN(Is=800.0E-18 Bf=333.3)
.model qmi PNP(Is=800.0E-18 Bf=1002)
.model qmo PNP(Is=800.0E-18 Bf=1000 Cjc=1E-15 Tr=59.42E-9)
e1 10 6 3 9 1
v1 10 11 dc 0
q5 5 11 6 qoc
.model qoc NPN(Is=800.0E-18 Bf=41.38E3 Cjc=1E-15 Tf=23.91E-12 Tr=24.01E-9)
dp 4 3 dx
rp 3 4 5.556E3
.model dx D(Is=800.0E-18 Rs=1)
*
.ends

ничего специфического в ней нет, должна работать в любом спайсе.