eZ430-F2013, впечатления Опции

[VVlad]

Просьба откликнуться тем, кто пользовался конроллером-конструктором eZ430-F2013.
1) На плате установлен МК MSP430x20x1. Правда ли, что его ток потребления всего лишь 220 мкА?
2) По какой технологии выполнен этот чип (мои версии - ABT, BTL, CMOS, TTL)?
В даташите на него указано " 16-Bit RISC Architecture, 62.5 ", но архитектура и технология - различные понятия или я не прав?

Думаем покупать этот набор, прошу знатоков посоветуйте, пожалуйста, на что обратить внимание?

[VVlad]

Спасибо, Резидент, за ясный ответ. Значит, трансиверов - посредников между MSP430 и USB в одном корпусе не существует. Единственный выход - ставить два корпуса последовательно - аналог MAX3232 и следом - мост.

[rezident]

Значит, трансиверов - посредников между MSP430 и USB в одном корпусе не существует. Единственный выход - ставить два корпуса последовательно - аналог MAX3232 и следом - мост.

Нет! Вы меня поняли совершенно неправильно. С точностью до "наоборот". Я же указал "мост USB-COM", а не USB-RS232. Хотя признаю, что более употребительными названиями этих конверторов являются названия USB-to-UART или USB-to-Serial Port. И вообще я рассчитывал, что вы сами посмотрите даташиты подобных м/с. Именно такой должен быть подход нормального инженера: узнать общую информацию, а подробности уточнять самостоятельно.
USB-to-UART от Silabs
USB-to-UART от FTDIchip
USB-to-Serial Bridge Controller от Prolific
USB-to-Serial Port Controller от Texas Instruments

[VVlad]

Нет! Вы меня поняли совершенно неправильно. С точностью до "наоборот". Я же указал "мост USB-COM", а не USB-RS232. Хотя признаю, что более употребительными названиями этих конверторов являются названия USB-to-UART или USB-to-Serial Port. И вообще я рассчитывал, что вы сами посмотрите даташиты подобных м/с. Именно такой должен быть подход нормального инженера: узнать общую информацию, а подробности уточнять самостоятельно.
USB-to-UART от Silabs
USB-to-UART от FTDIchip
USB-to-Serial Bridge Controller от Prolific
USB-to-Serial Port Controller от Texas Instruments

Приятно было узнать, что достаточно одного корпуса. С радостью сообщаю, что раздобыл FT232BM, установил драйверы и соединил с MSP430F2012. Это замечательно, что Резидент догадался поделится со мной ссылками. Именно их мне так не хватало ( )! Мои подозрения относительно того, что я неосторожно сжёг вывод 7 (P1.5/TA0), не поддтвердились. "Подрыгав" этой ножкой, убедился с помощью осциллографа в прямоугольных импульсах амплитудой 3 Вольта и частотой от 1Гц до 1 МГц (изменяя задержку). В FT232BM есть режим "адаптации" амплитуды сигналов к 3-вольтовой логике (достаточно оказалось замкнуть перемычкой выводы 6 и 13 (3v3out c VccIO)).
Бьюсь сейчас над вопросом, как отладить демо-код для эхо USART.

Код

;*******************************************************************************
;   MSP430F20xx Demo - Timer_A, Ultra-Low Pwr UART 2400 Echo, 32kHz ACLK
;
;   Description: Use Timer_A CCR0 hardware output modes and SCCI data latch
;   to implement UART function @ 2400 baud. Software does not directly read and
;   write to RX and TX pins, instead proper use of output modes and SCCI data
;   latch are demonstrated. Use of these hardware features eliminates ISR
;   latency effects as hardware insures that output and input bit latching and
;   timing are perfectly synchronised with Timer_A regardless of other
;   software activity. In the Mainloop the UART function readies the UART to
;   receive one character and waits in LPM3 with all activity interrupt driven.
;   After a character has been received, the UART receive function forces exit
;   from LPM3 in the Mainloop which echo's back the received character.
;   ACLK = TACLK = LFXT1 = 32768Hz, MCLK = SMCLK = default DCO
;   //* An external watch crystal is required on XIN XOUT for ACLK *//    
;
;                MSP430F20xx
;             -----------------
;         /|\|              XIN|-
;          | |                 | 32kHz
;          --|RST          XOUT|-
;            |                 |
;            |   CCI0B/TXD/P1.5|-------->
;            |                 | 2400 8N1
;            |   CCI0A/RXD/P1.1|<--------
;
;
;   M. Buccini / L. Westlund
;   Texas Instruments Inc.
;   October 2005
;   Built with IAR Embedded Workbench Version: 3.40A
;*******************************************************************************
RXD         EQU     002h                   ; RXD on P1.1
TXD         EQU     020h                   ; TXD on P1.5
;
;   CPU Registers Used
#define     RXTXData R4
#define     BitCnt   R5
;
;   Conditions for 2400 Baud SW UART, ACLK = 32768
Bitime_5    EQU     06    ; 2025        ; ~0.5 bit length + small adjustment
Bitime      EQU     014   ; 4725       ; 427us bit length ~ 2341 baud
#include  "msp430x20x3.h"
;-------------------------------------------------------------------------------
            ORG     0F800h                 ; Program Reset
;-------------------------------------------------------------------------------
RESET       mov.w   #0280h,SP              ; Initialize stackpointer
StopWDT     mov.w   #WDTPW+WDTHOLD,&WDTCTL ; Stop Watchdog Timer
SetupTA     mov.w   #TASSEL_1+MC_2,&TACTL  ; ACLK, continuous mode
SetupC0     mov.w   #OUT,&CCTL0            ; TXD Idle as Mark
SetupP1     bis.b   #TXD+RXD,&P1SEL        ;
            bis.b   #TXD,&P1DIR            ;
                                           ;
Mainloop    call    #RX_Ready              ; UART ready to RX one Byte
            bis.w   #LPM3+GIE,SR           ; Enter LPM3 w/ int until Byte RXed
            call    #TX_Byte               ; TX Back RXed Byte Received
            jmp     Mainloop               ;
                                           ;
;-------------------------------------------------------------------------------
TX_Byte  ; Subroutine Transmits Character from RXTXData Buffer
;-------------------------------------------------------------------------------
TX_1        mov.w   &TAR,&CCR0             ; Current state of TA counter
            cmp.w   &TAR,&CCR0             ; !!Prevent async capature!!
            jne     TX_1                   ;
            add.w   #Bitime,&CCR0          ; Some time till first bit
            bis.w   #0100h, RXTXData       ; Add mark stop bit to RXTXData
            rla.w   RXTXData               ; Add space start bit
            mov.w   #10,BitCnt             ; Load Bit counter, 8data + ST/SP
            mov.w   #CCIS0+OUTMOD0+CCIE,&CCTL0   ; TXD = mark = idle
TX_Wait     bit.w   #CCIE,&CCTL0           ; Wait for TX completion
            jnz     TX_Wait                ;
            ret                            ;
                                           ;
;-------------------------------------------------------------------------------
RX_Ready ; Subroutine Readies UART to Receive Character into RXTXData Buffer
;-------------------------------------------------------------------------------
            mov.w   #08,BitCnt             ; Load Bit Counter, 8 data bits
SetupRX     mov.w   #CM1+SCS+OUTMOD0+CAP+CCIE,&CCTL0 ; Neg Edge,Sync,cap
            ret                            ;
                                           ;
;-------------------------------------------------------------------------------
TA0_ISR ;  RXTXData Buffer holds UART Data
;-------------------------------------------------------------------------------
            add.w   #Bitime,&CCR0          ; Time to next bit
            bit.w   #CCIS0,&CCTL0          ; RX on CCI0B?
            jnz     UART_TX                ; Jump --> TX
UART_RX     bit.w   #CAP,&CCTL0            ; Capture mode = start bit edge
            jz      RX_Bit                 ; Start bit edge?
RX_Edge     bic.w   #CAP,&CCTL0            ; Switch to compare mode
            add.w   #Bitime_5,&CCR0        ; First databit 1.5 bits from edge
            reti                           ;
RX_Bit      bit.w   #SCCI,&CCTL0           ; Get bit waiting in receive latch
            rrc.b   RXTXData               ; Store received bit
RX_Test     dec.w   BitCnt                 ; All bits RXed?
            jnz     RX_Next                ; Next bit?
;>>>>>>>>>> Decode of Received Byte Here <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
RX_Comp     bic.w   #CCIE,&CCTL0           ; All bits RXed, disable interrupt
            mov.w   #GIE,0(SP)             ; Decode byte = active in Mainloop
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
RX_Next     reti                           ;
                                           ;
UART_TX     cmp.w   #00h,BitCnt            ;
            jne     TX_Next                ; Next bit?
            bic.w   #CCIE,&CCTL0           ; All Bits TX or RX, Disable Int.
            reti                           ;
TX_Next     bic.w   #OUTMOD2,&CCTL0        ; TX Mark
            rra.w   RXTXData               ; LSB is shifted to carry
            jc      TX_Test                ; Jump --> bit = 1
TX_Space    bis.w   #OUTMOD2,&CCTL0        ; TX Space
TX_Test     dec.w   BitCnt                 ; All bits sent (or received)?
            reti                           ;
                                           ;
;-------------------------------------------------------------------------------
;           Interrupt Vectors
;-------------------------------------------------------------------------------
            ORG     0FFFEh                 ; MSP430 RESET Vector
            DW      RESET                  ;
            ORG     0FFF2h                 ; Timer_A0 Vector
            DW      TA0_ISR                ;
            END

В главном цикле

Код

Mainloop    mov.w   #08,BitCnt             ; ЯвнаЯ загрузкЯ счётчика битов 8-ю шагами байта
mov.w   #0Fh,RXTXData             ; чтобы было что отослать через FT232, USB и далее - через VCP
;call    #RX_Ready              ; UART ready to RX one Byte
           ;bis.w   #LPM3+GIE,SR           ; Enter LPM3 w/ int until Byte RXed
            call    #TX_Byte               ; TX Back RXed Byte Received
            jmp     Mainloop               ;

Напрямую этот пример выполнить не удалось, поскольку , как заметил один из маляров,
в заголовке программы "MSP430F20xx Demo - Timer_A, Ultra-Low Pwr UART 2400 Echo, 32kHz ACLK "
намекается на то, что программа должна работать не только для MSP2013, но и для MSP2012.
Даже после замены строки #include "msp430x20x3.h" на #include "msp430x20x2.h" кристалл не откликнулся на наши просьбы.
Закомментарил вызов функции чтения и команду ("спать" до прерывания) и добавил над ними две строки с русскими комментариями, (откомпилировалась и скомпоновалась программа без единой ошибки),
подключил осциллограф, после запуска программы напряжение на выходе 7 (P1.5) вырастает до 3 вольт и не обнуляется. А я-то надеялся, что в цикле Mainloop будет постоянно выдаваться байт OF (четыре импульса одного уровня и четыре другого, не считая стартовых и стоповых битов).