генератор ПСП (m-последовательности) на XC9536 Опции

[8-)]

Доброе время суток. Помогите чайнику решить проблему, pls.
Никак не могу понять в чём проблема. Провожу моделирование в modelsim - всё работает. Прошиваю XC9536 - не работает. Вот код на vhdl:

library IEEE;
use IEEE.STD_LOGIC_1164.ALL;
use IEEE.STD_LOGIC_ARITH.ALL;
use IEEE.STD_LOGIC_UNSIGNED.ALL;

---- Uncomment the following library declaration if instantiating
---- any Xilinx primitives in this code.
library UNISIM;
use UNISIM.VComponents.all;

entity counter is
Port ( CLK : in std_logic;
DOUT : out std_logic_vector(7 downto 0));
end counter;

architecture Behavioral of counter is
signal regA: std_logic_vector(8 downto 0);
signal flag: std_logic;
begin

process (CLK)
begin

if (CLK'event and CLK='1') then

if flag = '1' then
regA <= (regA(4) xor regA(0)) & regA(8 downto 1);

DOUT(0) <= regA(0);
DOUT(1) <= regA(1);
DOUT(2) <= regA(2);
DOUT(3) <= regA(3);
DOUT(4) <= regA(4);
DOUT(5) <= regA(5);
DOUT(6) <= regA(8);
DOUT(7) <= regA(7);
else
flag <= '1';
regA(0) <= '1';
regA(1) <= '1';
regA(2) <= '1';
regA(3) <= '1';
regA(4) <= '1';
regA(5) <= '1';
regA(6) <= '1';
regA(7) <= '1';
regA(8) <= '1';
end if;
end if;
end process;

end Behavioral;

После прошивания микросхемы все сигналы DOUT имеют низкий уровень.

[disel]

Я когда-то делал универсальный генератор m-последовательностей следующим образом:

library IEEE;
use IEEE.STD_LOGIC_1164.all;
use IEEE.STD_LOGIC_ARITH.all;


entity GaloisPRNG is
generic(
PN : std_logic_vector := O"325"
);
port(
CLK : in STD_LOGIC;
PRN : in STD_LOGIC;
Q : out STD_LOGIC
);
end GaloisPRNG;


architecture rtl of GaloisPRNG is

function calcN (P : std_logic_vector) return natural is
variable tN : natural;
begin
tN := 0;
for i in P'Length-1 downto 0 loop
if P(i) = '1' then
tN := i;
end if;
end loop;
return P'Length - tN - 1;
end;

constant N : natural := calcN(PN);
signal A, X : STD_LOGIC_VECTOR(N-1 downto 0);
constant P : STD_LOGIC_VECTOR (N downto 0) := PN (PN'Length-N-1 to PN'Length-1);

begin

A(N-1) <= X(0);

process ( X )
begin
for i in N-2 downto 0 loop
if P(i+1) = '0' then
A(i) <= X(i+1);
elsif P(i+1) = '1' then
A(i) <= X(i+1) xor X(0);
end if;
end loop;
end process;

process ( CLK, PRN )
begin
if PRN = '0' then
X <= ( others => '1' );
elsif CLK'event and CLK = '1' then
X <= A;
end if;
end process;

Q <= X(0);

end rtl;

Задаешь нужный полином (PN) и получаешь желаемый генератор.