--=============================== PIXEL_CREATING =========================================
-- Данный модуль предназначен для приема 3 байт данных по UART и пребразования их
-- В одно слово, содержащее данные о цвете пикселя.

LIBRARY IEEE;
USE IEEE.STD_LOGIC_1164.ALL;
USE IEEE.NUMERIC_STD.ALL;

ENTITY PIXEL_CREATING IS
GENERIC
(
COLOR_DEPTH : INTEGER := 12 --COLOR_DEPTH/3 Для одного цвета
);
PORT
(
CLK : IN STD_LOGIC; -- Частота UART ресивера
UART_DATA : IN STD_LOGIC_VECTOR(7 DOWNTO 0); -- Данные, выдавемые UART
DATA_VALID : IN STD_LOGIC; -- Сигнал подтверждения валидных данных рессивером
ASY_RESET : IN STD_LOGIC; -- Асинхронный сброс Синхронизирован в топ модуле.
PIXEL_COLOR : OUT STD_LOGIC_VECTOR(COLOR_DEPTH-1 DOWNTO 0); -- Выходной сигнал который является цветом пикселя
PIXEL_VALID : OUT STD_LOGIC
);
END ENTITY;

ARCHITECTURE PIXEL_CREATING_arc OF PIXEL_CREATING IS
SIGNAL BYTE_CNT : INTEGER RANGE 0 TO 2 := 0; -- Счетчик принятых байт
SIGNAL RED_COLOR_REG : STD_LOGIC_VECTOR(COLOR_DEPTH/3-1 DOWNTO 0) := (OTHERS => '0'); -- Регистр куда записывается красная составляющая пикселя
SIGNAL GREEN_COLOR_REG : STD_LOGIC_VECTOR(COLOR_DEPTH/3-1 DOWNTO 0) := (OTHERS => '0'); -- Регистр куда записывается зеленая составляющая пикселя
SIGNAL BLUE_COLOR_REG : STD_LOGIC_VECTOR(COLOR_DEPTH/3-1 DOWNTO 0) := (OTHERS => '0'); -- Регистр куда записывается синяя составляющая пикселя
SIGNAL LOAD_DATA : STD_LOGIC := '0'; -- Сигнал разрешения объедениения данных
BEGIN
BYTE_COUNTER : PROCESS
(
CLK,
ASY_RESET
)
BEGIN
IF (ASY_RESET = '1') THEN
BYTE_CNT <= 0 ;
LOAD_DATA <= '0';
PIXEL_VALID <= '0';
RED_COLOR_REG <= (OTHERS => '0');
GREEN_COLOR_REG <= (OTHERS => '0');
BLUE_COLOR_REG <= (OTHERS => '0');
PIXEL_COLOR <= (OTHERS => '0');
ELSIF (CLK'EVENT AND CLK = '1') THEN
LOAD_DATA <= '0'; -- Постоянно держим сигнал разрешения в нуле
PIXEL_VALID <= '0'; -- Постоянно держим сигнал валидности пикселя в нуле

IF (DATA_VALID = '1') THEN -- Как только поступил сигнал валидности данных
CASE BYTE_CNT IS -- Начинаем анализировать состояние счётчика

WHEN 0 => -- Есть сигнал валидности и счтчик равен 0
RED_COLOR_REG <= UART_DATA(COLOR_DEPTH/3-1 DOWNTO 0); -- Значит это были данные о красном цвете пикселя
BYTE_CNT <= BYTE_CNT + 1; -- Инкрементируем счетчик на 1

WHEN 1 => -- Есть сигнал валидности и счтчик равен 1
GREEN_COLOR_REG <= UART_DATA(COLOR_DEPTH/3-1 DOWNTO 0); -- Значит это были данные о зеленом цвете пикселя
BYTE_CNT <= BYTE_CNT + 1; -- Инкрементируем счетчик на 1

WHEN 2 => -- Есть сигнал валидности и счтчик равен 2
BLUE_COLOR_REG <= UART_DATA(COLOR_DEPTH/3-1 DOWNTO 0); -- Значит это были данные о синем цвете пикселя
LOAD_DATA <= '1'; -- Разрешам следующим тактом "собрать пиксель"
BYTE_CNT <= 0 ; -- Обнулим счетчик

WHEN OTHERS => BYTE_CNT <= 0 ; -- Обнуляем счётчик если он вышел за диапазон счета
END CASE;
END IF;

IF (LOAD_DATA = '1') THEN -- Как только наступило разрешение сбора пикселя
PIXEL_VALID <= '1'; -- Значит следующим тактом у нас будет валидный пиксель
PIXEL_COLOR <= BLUE_COLOR_REG&GREEN_COLOR_REG&RED_COLOR_REG; -- Соберем его
END IF;

END IF;
END PROCESS;
END ARCHITECTURE;

mode com5 baud=9600 parity=n data=8
copy D:\bit /b com5
pause