module    SerialOut
;
;    File:    sout.s90
;
;    08-Sep-05 BK    Initial edit
;    28-Sep-05 BK    Last  update
;
$fmacros.inc
;
; External references
;
;    extern    N$BITS            ; The number of bits to be transmitted
N$BITS    =    16                ;
    extern    SDAT$PORT, SDAT$BIT, SDAT$DDR; The data output port
    extern    SCLK$PORT, SCLK$BIT, SCLK$DDR; Clock control port

    rseg    CODE    ; Code segment
;
; ** SerialOut    -- the function outputs N$BITS of data serially through
;        the SDAT$BIT of the MCU port SDAT$PORT. The output starts
;        from the MSB of data.
; ASM usage:
;    r16 - low byte of data;
;    r17 - high byte of data;
;    r18 - the number of bits (N$BITS) for output.
; C usage:
;    void SerialOut(unsigned data, char nbits);

;
; ** SerialOutW    -- the same as the function above, but N$BITS is 16.
;
; ASM usage:
;    r16 - low byte of data;
;    r17 - high byte of data;
; C usage:
;    void SerialOutW(unsigned data);
;
    ENTRY$    SerialOutW
    ldi    r18, N$BITS    ; Set bit counter
    ENTRY$    SerialOut
?0:    sbrs    r17, 7        ; Form a data bit
    cbi    SDAT$PORT, SDAT$BIT    ;
    sbrc    r17, 7            ;
    sbi    SDAT$PORT, SDAT$BIT    ;
    sbi    SCLK$PORT, SCLK$BIT; Form a clock pulse
    lsl    r16            ; (Shift word of data left)
    rol    r17            ;;
    cbi    SCLK$PORT, SCLK$BIT    ;
    dec    r18        ; Bump counter
    brne    ?0        ; Loop if not done yet

    ret
;
; ** InitSerial    -- the function initiates serial port.
;
; C usage:
;    void InitSerial(void);
;
    ENTRY$    InitSerial
    sbi    SCLK$DDR, SCLK$BIT; Set serial port as output
    sbi    SDAT$DDR, SDAT$BIT    ;
    cbi    SCLK$PORT, SCLK$BIT; Set initial levels on clock
    cbi    SDAT$PORT, SDAT$BIT; and data bits
    ret

    end