Чудеса, паразитные импульсы Опции

[MySOL]

Друзья, выручайте. Возникли проблемы с получением генератора прямоугольных импульсов. Микроконтроллер ATMEGA48. Вобщем суть такова: для одной схемки нужно было прилепить пул ап к выводу и на определённый промежуток прижимать его к земле. В протеусе всё летает как нужно. В итоге перенёс все на железо и тут понеслось: ничего не работает.(Это просто лирическое отступление и в суть программы вдаваться не стоит). Долго маялся и не мог понять в чём проблема. В итоге запилил простейший генератор прямоугольного сигнала и вот что я увидел на экране осциллографа:


Я уже несколько недель маюсь с этой проблемой. Думал, что проблема в питалове. Подключал и ЛБП и батарейки. На входе стоит кондер на 10 мкф, такты задаются кварцем на 12 МГц. Пробовал и на внутреннем rc, ничего не изменилось. Есть ли какие нибудь соображения?

А по поводу той программки, что я писал вначале. Она должна прижать ногу микрухи на 500 мкс. На осциллографе этого не происходило, был просто моментальный скачёк до 0 и тут же отпускал:


И ещё я пробовал на 2 микрухах везде оно и то же.

[ILYAUL]

Что-то мне подсказывает , что проблемка именно а программке, ибо протеус вещь не подвластная разуму.

[MySOL]

Что-то мне подсказывает , что проблемка именно а программке, ибо протеус вещь не подвластная разуму.

Код

RES_DS:        LDI        TEMP,    0B00000000        ; Сброс
                    OUT        PORTB,    TEMP            ; Посылаем 0 в течении 500 мкс

                    LDI        DELAY1,    RP/3            ;RP=500 ( указан DSEG)

                    SUBI      DELAY1,    1                ; Задержка 500 мкс
                    BRNE            PC-1                    ;

                     CBI        DDRB,    0                ; Меняем вывод на ввод
            
                    SBIC     PINB,    0                ; Ждём пока датчик утопит шину
                     RJMP     PC-1

                    SBIS     PINB,    0                ; Ждём пока датчик будет готов к
                    RJMP     PC-1                    ; следующей команде

                    RET

Вобщем говоря это подпрограмма для 1-WIRE программы для проверки готовности датчика. Отправляем 0 в течении 500 мкс после чего ждём ответ ( в виде 0) от датчика. Думаю программа вполне понятна и объяснений не требует. И опять же повторюсь в протеусе осциль показал все как надо. А вот на железке задержка в 500 мкс отсутствует ( вторая картинка). Я прошу прощения. Тут скорее всего без нормальной осциллограмы мало что понятно. Я надеялся, что возможно с этим уже кто-то сталкивался. Я постараюсь сегодня завтра скинуть их. Просто у меня флешки сейчас нету

[=GM=]

Код

   LDI    DELAY1,    RP/3;RP=500 ( указан DSEG)
   SUBI      DELAY1,    1; Задержка 500 мкс
   BRNE      PC-1    ;

При 12 МГц тактовой и однобайтном счётчике, у вас программная задержка будет максимум на 64 мкс, а не на 500 мкс.
Вам следует использовать 2-х байтный счётчик задержки. Вернее всего, датчик у вас нормальный, просто не успевает
среагировать на короткий импульс.

Ниже, для примера, приведен реальный код для начала работы с 1-wire, вроде бы Fклок=10 МГц, проверьте

Код

rs1820:
    cbi    PORTB,0
    ldi    hdelay,high(1249);500us
    ldi    ldelay,low(1249)
rs1:    sbiw    ldelay,1
    brne    rs1
    sbi    PORTB,0
    ldi    temp1,0x1E    ;PB0-input
    out    DDRB,temp1
    ldi    hdelay,high(169);68us
    ldi    ldelay,low(169)
rs2:    sbiw    ldelay,1
    brne    rs2
    ldi    temp3,13    ;TempSensor failed
    sbic    PINB,0
    rjmp    rs4
    ldi    hdelay,high(1079);432us
    ldi    ldelay,low(1079)
rs3:    sbiw    ldelay,1
    brne    rs3
    ldi    temp1,0x1F    ;PB0-output
    out    DDRB,temp1
    clc
    ret
rs4:    ldi    temp1,0x1F    ;PB0-output
    out    DDRB,temp1
    ret