Помощь - Поиск - Пользователи - Календарь
Полная версия этой страницы: Размещение части функций в отдельной секции
Форум разработчиков электроники ELECTRONIX.ru > Микроконтроллеры (MCs) > Cредства разработки для МК > GNU/OpenSource средства разработки
MrYuran
May 23 2011, 09:41
Добрый день, уважаемые знатоки!
Тема такая:
Необходимо часть функций (т.н. метрологически значимые) разместить в отдельной секции, чтобы сформировать по ним отдельную контрольную сумму.
Компилятор - MSPGCC.
Делаем так:

объявляем секцию в makefile
Код
LDFLAGS += -Wl,--section-start
LDFLAGS += -Wl,.metrology=0xB000


Размещаем в этой секции необходимые функции:
Код
void ShowMiddleTemp(struct IND_PARAMS_Channel *stParams, unsigned char ucCol, unsigned char ucPage) __attribute__ (( section(".metrology") ));


Вызываем функцию, использующую адреса границ нашей секции:
Код
extern unsigned short __start_metrology;
            extern unsigned short __stop_metrology;

unsigned short  *addr_start = &__start_metrology;
unsigned short  *addr_stop = &__stop_metrology;


MyCRC32 = Crc32(addr_start, (addr_stop - addr_start));


========================================

Результат: undefined reference to `__start_metrology'

Выдержки из .map и .lst и .elf:

Код
.metrology      0x0000b000      0x57a

__start_metrology                                 ./Obj/ххх.o
__stop_metrology                                  ./Obj/ххх.o

Address of section .metrology set to 0xb000

SYMBOL TABLE:
0000b000 l    d  .metrology00000000 .metrology

Section Headers:
  [Nr] Name              Type            Addr     Off    Size   ES Flg Lk Inf Al
  [ 0]                   NULL            00000000 000000 000000 00      0   0  0
  [ 1] .metrology        PROGBITS        0000b000 0097d8 00057a 00  AX  0   0  2


То есть, по всему видно, что секция создана, она не пустая и включена в конечную прошивку.
Но при этом ссылки на её границы не определены.

Какие будут мысли?

PS; что характерно, идентификаторы встроенных секций (например, _vectors_end) распознаются без проблем.
klen
May 23 2011, 10:06
предлагаю сделать чуток иначе.

объявляете в скрипте линкера секцию
Код
MEMORY
{
  flash   (rx)  : ORIGIN = ....., LENGTH = ....
  metrology (rx) : ORIGIN = 0xB000, LENGTH=.....
  ram    (rwx)  : ORIGIN =.....,   LENGTH = ....
  ..............

  ..............
}

SECTIONS
{
    . = 0;    
                                
    .text :
       {
        ..........................
       } >flash
        .metrology
      {
          __start_metrology = .
          *(.metrology)
      *(.metrology*)
         __stop_metrology = .
      } >flash



Цитата
PS; что характерно, идентификаторы встроенных секций (например, _vectors_end) распознаются без проблем.

эта характерность станет очевидной если вы взглянене в скрипт линкера - я телепатически уверен что там описана секция vectors с метками границ секции, они становятся доступны при линковке, пример сверху эту очевидность прикручиваетк Вашей секции.

Вам тупо нада разобратся как работает линкер и поковырятся в скрипте. если неполучится сообщайте.
Axel
May 23 2011, 10:08
Попробуйте так:
Код
unsigned short *addr_start = (unsigned short *)((unsigned short)(&_start_metrology))
MrYuran
May 23 2011, 10:11
Цитата(klen @ May 23 2011, 14:06) *
предлагаю сделать чуток иначе.

объявляете в скрипте линкера секцию...

Это понятно, но идеологически неправильно.
Да и размер заранее (как бы) неизвестен
klen
May 23 2011, 10:14
Цитата(Axel @ May 23 2011, 14:08) *
Попробуйте так:
Код
unsigned short *addr_start = (unsigned short *)((unsigned short)(&_start_metrology))

мысль глубокая и интересная но вопрос остется открытым - а где линкеру брать адрес _start_metrology

Цитата(MrYuran @ May 23 2011, 14:11) *
Это понятно, но идеологически неправильно.
Да и размер заранее (как бы) неизвестен

вы же не сказали деталей ...
тогда смело вносите свою секцию как подсекцию .text и тогда все будет идеологически правильно
мне не совсем понятно зачем ее по фиксированному адресу размещать это раз
размер заранее известен - верхний край флеша! это два
MrYuran
May 23 2011, 10:15
Цитата(klen @ May 23 2011, 14:12) *
мысль глубокая и интересная но вопрос остется открытым - а где линкеру брать адрес _start_metrology

Интересный тогда вопрос - а кто размещает секции, разве не он?
Ведь функции размещены где надо, с адреса B000.
Почему при размещении функций адрес известен, а при обращении к _start_metrology - нет?
klen
May 23 2011, 10:15
Цитата(MrYuran @ May 23 2011, 14:15) *
Интересный тогда вопрос - а кто размещает секции, разве не он?
Ведь функции размещены где надо, с адреса B000.
Почему при размещении функций адрес известен, а при обращении к _start_metrology - нет?

линкер не размещает - он кладет туда куда Вы разместили их в скрипте линкера

ну ж написал - _start_metrology не объявлена в скрипте линкера! он ниоткуда не выдумывается линкером. иначе я бы мог сказать '' а почему при обращении к _super_puper_mega_start__metrology тоже проблемы какието ". это ВЫ!!! должны _start_metrology определить.
dimka76
May 23 2011, 10:16
Цитата(MrYuran @ May 23 2011, 14:15) *
Интересный тогда вопрос - а кто размещает секции, разве не он?
Ведь функции размещены где надо, с адреса B000.
Почему при размещении функций адрес известен, а при обращении к _start_metrology - нет?


может быть дело в количестве подчеркиваний перед start и stop ?
В первом сообщении у вас их было два.
Axel
May 23 2011, 10:18
Цитата(klen @ May 23 2011, 13:14) *
мысль глубокая и интересная но вопрос остется открытым - а где линкеру брать адрес _start_metrology


Без проблем находит... С Crossworks'ом я такое часто пользую.
MrYuran
May 23 2011, 10:19
Цитата(klen @ May 23 2011, 14:14) *
тогда смело вносите свою секцию как подсекцию .text и тогда все будет идеологически правильно

Как это сделать?


Цитата(dimka76 @ May 23 2011, 14:16) *
может быть дело в количестве подчеркиваний перед start и stop ?
В первом сообщении у вас их было два.

Нет, уже пробовали. sm.gif
Как и различные приведения типов.

Таки придётся линкер изучать sad.gif
klen
May 23 2011, 10:19
Цитата(Axel @ May 23 2011, 14:18) *
Без проблем находит... С Crossworks'ом я такое часто пользую.

ну если у вас оно само работает то я значит ничего не понимаю. sad.gif


2_MrYuran
добавте в описание вотэто;

.text
{
..........
.metrology
{
__start_metrology = . /* объявление символа адрес которого будет при линковке доступен по имени */
*(.metrology) /* сюда линкер сложит код с атрибутом секции metrology */
*(.metrology*) /* сюда линкер сложит код с атрибутом секции metrology */
__stop_metrology = . /* объявление символа адрес которого будет при линковке доступен по имени */
..........
}

должно работать. тока теперь адрес начала не фиксированнный . хотя в принципе можно попробываить уговорить сделать дыру в прошивке.
MrYuran
May 23 2011, 10:25
Ладно, начинаем по порядку.
Код
LDFLAGS += -Wl,--section-start
LDFLAGS += -Wl,.metrology=0xB000


Объявляем линкеру собственную секцию и привязываем её к фиксированному адресу.
Собственно, с этого момента у него вся инфа есть. (ну разве что конец подсчитать после размещения всех функций).
klen
May 23 2011, 10:28
Цитата(MrYuran @ May 23 2011, 14:25) *
Ладно, начинаем по порядку.
Код
LDFLAGS += -Wl,--section-start
LDFLAGS += -Wl,.metrology=0xB000


Объявляем линкеру собственную секцию и привязываем её к фиксированному адресу.
Собственно, с этого момента у него вся инфа есть. (ну разве что конец подсчитать после размещения всех функций).

я с командной строки ничего так незасовывал линкеру - все чеерз скрипт - теже яйца но документально оформленные в виде файла, по идее должно работать но мне не очевидно как указать какой секции соответствует --section-start... я их могу в командной строке передать милион и секций и символов - где соответствие, потом я не вижу объявление символа конца секции... советую не морочить себе голову сделать через скрипт а когда появится свободное время разобратся в косяках
Axel
May 23 2011, 10:33
Работающий код:
Код
gAppParamPage = ((u32)&__FLASH_segment_used_end__ + FLASH_PAGE_SIZE) & ~(FLASH_PAGE_SIZE - 1);


В .map:
Код
__FLASH_segment_used_end__ = (ALIGN ((__fast_load_start__ + SIZEOF (.fast)), 0x4) + SIZEOF (.data))


Собирается без проблем.
MrYuran
May 23 2011, 10:36
Цитата(klen @ May 23 2011, 14:28) *
советую не морочить себе голову сделать через скрипт а когда появится свободное время разобратся в косяках

Посоветуйте ещё, где по скриптам линкера толковая инфа.
Желательно прямой ссылкой.
Thnks.
MrYuran
May 23 2011, 13:25
Чего-то не выходит каменный цветок...
То ли лыжи сломались...
Вот исходный скрипт:
CODE

/* Default linker script, for normal executables */
OUTPUT_FORMAT("elf32-msp430","elf32-msp430","elf32-msp430")
OUTPUT_ARCH(msp:14)
MEMORY
{
text (rx) : ORIGIN = 0x1100, LENGTH = 0xeee0
data (rwx) : ORIGIN = 0x0200, LENGTH = 2048
vectors (rw) : ORIGIN = 0xffe0, LENGTH = 32
bootloader(rx) : ORIGIN = 0x0c00, LENGTH = 1K
infomem(rx) : ORIGIN = 0x1000, LENGTH = 256
infomemnobits(rx) : ORIGIN = 0x1000, LENGTH = 256
}
SECTIONS
{
/* Read-only sections, merged into text segment. */
.hash : { *(.hash) }
.dynsym : { *(.dynsym) }
.dynstr : { *(.dynstr) }
.gnu.version : { *(.gnu.version) }
.gnu.version_d : { *(.gnu.version_d) }
.gnu.version_r : { *(.gnu.version_r) }
.rel.init : { *(.rel.init) }
.rela.init : { *(.rela.init) }
.rel.text :
{
*(.rel.text)
*(.rel.text.*)
*(.rel.gnu.linkonce.t*)
}
.rela.text :
{
*(.rela.text)
*(.rela.text.*)
*(.rela.gnu.linkonce.t*)
}
.rel.fini : { *(.rel.fini) }
.rela.fini : { *(.rela.fini) }
.rel.rodata :
{
*(.rel.rodata)
*(.rel.rodata.*)
*(.rel.gnu.linkonce.r*)
}
.rela.rodata :
{
*(.rela.rodata)
*(.rela.rodata.*)
*(.rela.gnu.linkonce.r*)
}
.rel.data :
{
*(.rel.data)
*(.rel.data.*)
*(.rel.gnu.linkonce.d*)
}
.rela.data :
{
*(.rela.data)
*(.rela.data.*)
*(.rela.gnu.linkonce.d*)
}
.rel.ctors : { *(.rel.ctors) }
.rela.ctors : { *(.rela.ctors) }
.rel.dtors : { *(.rel.dtors) }
.rela.dtors : { *(.rela.dtors) }
.rel.got : { *(.rel.got) }
.rela.got : { *(.rela.got) }
.rel.bss : { *(.rel.bss) }
.rela.bss : { *(.rela.bss) }
.rel.plt : { *(.rel.plt) }
.rela.plt : { *(.rela.plt) }
/* Internal text space. */
.text :
{
. = ALIGN(2);
*(.init)
KEEP(*(.init))
*(.init0) /* Start here after reset. */
KEEP(*(.init0))
*(.init1) /* User definable. */
KEEP(*(.init1))
*(.init2) /* Initialize stack. */
KEEP(*(.init2))
*(.init3) /* Initialize hardware, user definable. */
KEEP(*(.init3))
*(.init4) /* Copy data to .data, clear bss. */
KEEP(*(.init4))
*(.init5) /* User definable. */
KEEP(*(.init5))
*(.init6) /* C++ constructors. */
KEEP(*(.init6))
*(.init7) /* User definable. */
KEEP(*(.init7))
*(.init8) /* User definable. */
KEEP(*(.init8))
*(.init9) /* Call main(). */
KEEP(*(.init9))
__ctors_start = . ;
*(.ctors)
KEEP(*(.ctors))
__ctors_end = . ;
__dtors_start = . ;
*(.dtors)
KEEP(*(.dtors))
__dtors_end = . ;
. = ALIGN(2);
*(.text)
. = ALIGN(2);
*(.text.*)
. = ALIGN(2);
*(.fini9) /* Jumps here after main(). User definable. */
KEEP(*(.fini9))
*(.fini8) /* User definable. */
KEEP(*(.fini8))
*(.fini7) /* User definable. */
KEEP(*(.fini7))
*(.fini6) /* C++ destructors. */
KEEP(*(.fini6))
*(.fini5) /* User definable. */
KEEP(*(.fini5))
*(.fini4) /* User definable. */
KEEP(*(.fini4))
*(.fini3) /* User definable. */
KEEP(*(.fini3))
*(.fini2) /* User definable. */
KEEP(*(.fini2))
*(.fini1) /* User definable. */
KEEP(*(.fini1))
*(.fini0) /* Infinite loop after program termination. */
KEEP(*(.fini0))
*(.fini)
KEEP(*(.fini))
_etext = .;
} > text
.data :
{
PROVIDE (__data_start = .) ;
. = ALIGN(2);
*(.data)
*(SORT_BY_ALIGNMENT(.data.*))
. = ALIGN(2);
*(.gnu.linkonce.d*)
. = ALIGN(2);
_edata = . ;
} > data AT > text
PROVIDE (__data_load_start = LOADADDR(.data) );
PROVIDE (__data_size = SIZEOF(.data) );
/* Bootloader. */
.bootloader :
{
PROVIDE (__boot_start = .) ;
*(.bootloader)
. = ALIGN(2);
*(.bootloader.*)
} > bootloader
/* Information memory. */
.infomem :
{
*(.infomem)
. = ALIGN(2);
*(.infomem.*)
} > infomem
/* Information memory (not loaded into MPU). */
.infomemnobits :
{
*(.infomemnobits)
. = ALIGN(2);
*(.infomemnobits.*)
} > infomemnobits
.bss :
{
PROVIDE (__bss_start = .) ;
*(.bss)
*(SORT_BY_ALIGNMENT(.bss.*))
*(COMMON)
PROVIDE (__bss_end = .) ;
_end = . ;
} > data
PROVIDE (__bss_size = SIZEOF(.bss) );
.noinit :
{
PROVIDE (__noinit_start = .) ;
*(.noinit)
*(.noinit.*)
*(COMMON)
PROVIDE (__noinit_end = .) ;
_end = . ;
} > data
.vectors :
{
PROVIDE (__vectors_start = .) ;
*(.vectors*)
KEEP(*(.vectors*))
_vectors_end = . ;
} > vectors
/* Stabs for profiling information*/
.profiler 0 : { *(.profiler) }
/* Stabs debugging sections. */
.stab 0 : { *(.stab) }
.stabstr 0 : { *(.stabstr) }
.stab.excl 0 : { *(.stab.excl) }
.stab.exclstr 0 : { *(.stab.exclstr) }
.stab.index 0 : { *(.stab.index) }
.stab.indexstr 0 : { *(.stab.indexstr) }
.comment 0 : { *(.comment) }
/* DWARF debug sections.
Symbols in the DWARF debugging sections are relative to the beginning
of the section so we begin them at 0. */
/* DWARF 1 */
.debug 0 : { *(.debug) }
.line 0 : { *(.line) }
/* GNU DWARF 1 extensions */
.debug_srcinfo 0 : { *(.debug_srcinfo) }
.debug_sfnames 0 : { *(.debug_sfnames) }
/* DWARF 1.1 and DWARF 2 */
.debug_aranges 0 : { *(.debug_aranges) }
.debug_pubnames 0 : { *(.debug_pubnames) }
/* DWARF 2 */
.debug_info 0 : { *(.debug_info) *(.gnu.linkonce.wi.*) }
.debug_abbrev 0 : { *(.debug_abbrev) }
.debug_line 0 : { *(.debug_line) }
.debug_frame 0 : { *(.debug_frame) }
.debug_str 0 : { *(.debug_str) }
.debug_loc 0 : { *(.debug_loc) }
.debug_macinfo 0 : { *(.debug_macinfo) }
/* DWARF 3 */
.debug_pubtypes 0 : { *(.debug_pubtypes) }
.debug_ranges 0 : { *(.debug_ranges) }
PROVIDE (__stack = 0xa00) ;
PROVIDE (__data_start_rom = _etext) ;
PROVIDE (__data_end_rom = _etext + SIZEOF (.data)) ;
PROVIDE (__noinit_start_rom = _etext + SIZEOF (.data)) ;
PROVIDE (__noinit_end_rom = _etext + SIZEOF (.data) + SIZEOF (.noinit)) ;
PROVIDE (__subdevice_has_heap = 0) ;
}


Нажмите для просмотра прикрепленного файла

Куда надо вставлять вышеописанный кусок с подсекцией?

Пробовали в разные места, выдаёт ошибку либо на строке с названием новой секции, либо на { следом за ней.
dimka76
May 24 2011, 04:31
Цитата(MrYuran @ May 23 2011, 17:25) *
Чего-то не выходит каменный цветок...
То ли лыжи сломались...


Куда надо вставлять вышеописанный кусок с подсекцией?

Пробовали в разные места, выдаёт ошибку либо на строке с названием новой секции, либо на { следом за ней.


Вот такой цветочек у меня вышел
Код
.text :
    {
        KEEP(*(.isr_vector .isr_vector.*))
        *(.text .text.* .gnu.linkonce.t.*)           
        *(.glue_7t) *(.glue_7)                        
        *(.rodata .rodata* .gnu.linkonce.r.*)
        __start_metrology = .;
        *(.metrology .metrology.* .gnu.linkonce.t.*)
        __stop_metrology = .;                              
    } > rom


И выдержки из map файла

Код
.rodata        0x08000d4b       0x10 release/obj/USART.o
                0x08000d4b                HEX
.rodata.str1.1
                0x08000d5b        0x3 release/obj/USART.o
                                  0x6 (size before relaxing)
*fill*         0x08000d5e        0x2 00
.rodata        0x08000d60       0x1c release/obj/Encoder.o
                0x08000d60                LCD_time_add
                0x08000d6c                pos
                0x08000d70                val_delta
.rodata.str1.1
                0x08000d7c       0x1e release/obj/Encoder.o
                                 0x21 (size before relaxing)
                0x08000d9a                __start_metrology = .
*(.metrology .metrology.* .gnu.linkonce.t.*)
*fill*         0x08000d9a        0x2 00
.metrology     0x08000d9c       0x24 release/obj/main.o
                0x08000d9c                ShowMiddleTemp
                0x08000dc0                __stop_metrology = .

.vfp11_veneer   0x08000dc0        0x0
.vfp11_veneer  0x00000000        0x0 linker stubs



Цитата(MrYuran @ May 23 2011, 14:36) *
Посоветуйте ещё, где по скриптам линкера толковая инфа.
Желательно прямой ссылкой.
Thnks.

Нажмите для просмотра прикрепленного файла
alx2
May 24 2011, 04:31
Цитата(MrYuran @ May 23 2011, 15:36) *
Посоветуйте ещё, где по скриптам линкера толковая инфа.
Желательно прямой ссылкой.
http://sourceware.org/binutils/docs/ld/Scripts.html
Для просмотра полной версии этой страницы, пожалуйста, пройдите по ссылке.
Invision Power Board © 2001-2025 Invision Power Services, Inc.